/*----------------------------------------------------------------------------
 PC Speaker Speech Synthesis
 (Straght port from Borland Pascal/DOS)
 Copyright (C) 1995, 2012 David Olofson <david@olofson.net>

 This software is provided 'as-is', without any express or implied warranty.
 In no event will the authors be held liable for any damages arising from the
 use of this software.

 Permission is granted to anyone to use this software for any purpose,
 including commercial applications, and to alter it and redistribute it
 freely, subject to the following restrictions:

 1. The origin of this software must not be misrepresented; you must not
    claim that you wrote the original software. If you use this software
    in a product, an acknowledgment in the product documentation would be
    appreciated but is not required.
 2. Altered source versions must be plainly marked as such, and must not be
    misrepresented as being the original software.
 3. This notice may not be removed or altered from any source distribution.
----------------------------------------------------------------------------*/

def period 16

TH()
{
	w square
	5 {
		a 1, set a
		p 300f,			d 1
		p (2000f + (rand .5)),	d 1
		p (2000f + (rand .5)),	d 1
		a 0, set a,		d (period - 3)
	}
}

D()
{
	w square,	d 20
	a 1, set a
	p 1000f,	d 1
	p 600f,		d 2
	p 400f,		d 3
	p 300f,		d 4
	p 200f,		d 5
	p 100f,		d 6
	a 0, set a
}

DG()
{
	w square, a 1, set a
	p 200f,		d 5
	p 100f,		d 6
	4 {
		a 1, set a, p 300f,	d 1
		p (3000f + (rand .5)),	d 1
		p (3000f + (rand .5)),	d 1
		a 0, set a,		d (period - 3)
	}
}

V()
{
	w square
	5 {
		a 1, set a
		p 300f,		d 1
		8 {
			p (4000f + (rand .75)),	d 1
		}
		a 0, set a,	d 7
	}
}

S()
{
	w square
	a 1, set a
	70 {
		p (5000f + (rand .8)),	d 1
	}
	a 0, set a
}

SH()
{
	w square
	a 1, set a
	150 {
		p (2000f + (rand .5)),	d 1
	}
	a 0, set a
}

T()
{
	w square
	d 40
	a 1, set a
	10 {
		p (3000f + (rand 1.2)),	d 1
	}
	a 0, set a
}

HT()
{
	w square
	d 20
	a 1, set a
	10 {
		p (2000f + (rand .5)),	d 1
	}
	a 0, set a
}

K()
{
	w square
	d 30
	a 1, set a
	16 {
		p (1000f + (rand 1)),	d 1
	}
	a 0, set a
}

O()
{
	w square
	8 {
		a 1, set a, p 740f,	d 1
		a 0, set a,		d (period - 1)
	}
}

R()
{
	w square
	8 {
		a 1, set a, p 900f,	d 1
		a 0, set a,		d (period - 1)
	}
}

EH()
{
	w square
	6 {
		a 1, set a, p 1500f,	d 1
		a 0, set a,		d (period - 1)
	}
}

ER()
{
	w square
	14 {
		a 1, set a, p 700f,	d 1
		a 0, set a,		d (period - 1)
	}
}

EE()
{
	w square
	8 {
		a 1, set a, p 2000f,	d 1
		a 0, set a,		d (period - 1)
	}
}

A()
{
	w square
	8 {
		a 1, set a, p 1100f,	d 1
		a 0, set a,		d (period - 1)
	}
}

AH()
{
	w square
	8 {
		a 1, set a, p 900f,	d 1
		a 0, set a,		d (period - 1)
	}
}

EEEE()
{
	w square
	12 {
		a 1, set a, p 2200f,	d 1
		a 0, set a,		d (period - 1)
	}
}

AI()
{
	run AH
	p 800f
	8 {
		a 1, set a, +p .15,	d 1
		a 0, set a,		d (period - 1)
	}
	run EEEE
}

M()
{
	w square
	10 {
		a 1, set a, p 5000f,	d .25
		a 0, set a,		d (period - .25)
	}
}

N()
{
	w square
	10 {
		a 1, set a, p 65f,	d 1
		a 0, set a,		d (period - 1)
	}
}

P()
{
	w square
	d 40
	a 1, set a
	p 200f,	d 3
	p 100f,	d 4
	p 65f,	d 6
	a 0, set a
}

Emergency()
{
	run EE
	run M
	run ER
	run DG
	run EH
	run N
	run S
	run EE
}

IAmPC()
{
	run AI
	d 60
	run A, run M
	d 50
	run P, run EEEE, d 10, run S, run EEEE
}

ISeekRevenge()
{
	run AI
	d 60
	run S, run EEEE, run K
	d 60
	run R, run EE, run V, run EH, run N, run DG
}

ThisIsAReal()
{
	run TH, run EE, run S
	d 50
	run EE, run S
	d 30
	run ER
	d 30
	run R, run EEEE, run A, run R
}

Talk(pitch vel=1)
{
	vol vel
	run Emergency,		d 200
	run Emergency,		d 200
	run Emergency,		d 300
	run IAmPC,		d 300
	run ISeekRevenge,	d 300
	run ThisIsAReal, d 60, run Emergency
}

TalkRVB()
{
	Talk 0 1,	d 20
	Talk 0 .5,	d 35
	Talk 0 .5,	d 200
	Talk 0 .3,	d 250
	Talk 0 .15,	d 300
	Talk 0 .075
}